010

• Contributor: Egon Willighagen

• License: http://creativecommons.org/publicdomain/zero/1.0/

• Uses method in: https://www.wikidata.org/wiki/Wikidata:WikiProject_Retractions/SPARQL

rq turtle/ttl

• retraction
• wikidata

Wikidata statements with a retracted paper as reference.

Use at

• https://qlever.dev/api/wikidata

PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX prov: <http://www.w3.org/ns/prov#>
PREFIX pr: <http://www.wikidata.org/prop/reference/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT DISTINCT ?entity ?entityLabel ?propertyLabel ?valueLabel ?retracted ?retractedLabel WHERE {
  ?retracted wdt:P31 wd:Q45182324 .
  ?entity ?p ?statement .
  ?statement prov:wasDerivedFrom / pr:P248 ?retracted .
  ?p ^wikibase:claim ?property .
  ?statement ?ps ?value .
  ?ps ^wikibase:statementProperty ?property .
  ?entity rdfs:label ?entityLabel . FILTER (LANG(?entityLabel) = "en") .
  ?property rdfs:label ?propertyLabel . FILTER (LANG(?propertyLabel) = "en") .
  ?value rdfs:label ?valueLabel . FILTER (LANG(?valueLabel) = "en") .
  ?retracted rdfs:label ?retractedLabel . FILTER (LANG(?retractedLabel) = "en") .
}

graph TD
classDef projected fill:lightgreen;
classDef literal fill:orange;
classDef iri fill:yellow;
  v6("?entity"):::projected 
  v4("?entityLabel"):::projected 
  v7("?p")
  v9("?property")
  v3("?propertyLabel"):::projected 
  v10("?ps")
  v5("?retracted"):::projected 
  v1("?retractedLabel"):::projected 
  v8("?statement")
  v11("?value")
  v2("?valueLabel"):::projected 
  a1((" "))
  c3(["wd:Q45182324"]):::iri 
  f0[["?retractedLabel = 'en'"]]
  f0 --> v1
  f1[["?valueLabel = 'en'"]]
  f1 --> v2
  f2[["?propertyLabel = 'en'"]]
  f2 --> v3
  f3[["?entityLabel = 'en'"]]
  f3 --> v4
  v5 --"wdt:P31"-->  c3
  v6 -->v7--> v8
  v8 --"prov:wasDerivedFrom"-->  a1
  a1 --"pr:P248"-->  v5
  v9 --"wikibase:claim"-->  v7
  v8 -->v10--> v11
  v9 --"wikibase:statementProperty"-->  v10
  v6 --"rdfs:label"-->  v4
  v9 --"rdfs:label"-->  v3
  v11 --"rdfs:label"-->  v2
  v5 --"rdfs:label"-->  v1