251

• License: https://www.gnu.org/licenses/gpl-3.0

• Uses method in: https://github.com/WDscholia/scholia/tree/master/scholia/app/templates/work_topic-scores.sparql

rq turtle/ttl

Work aspect: topic scores

Use at

• https://query.wikidata.org/sparql

PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
#defaultView:BubbleChart

PREFIX target: <http://www.wikidata.org/entity/Q28942417>

SELECT ?score ?topic ?topicLabel
WITH {
  SELECT
    (SUM(?score_) AS ?score)
    ?topic
  WHERE {
    { 
      target: wdt:P921 ?topic .
      BIND(20 AS ?score_)
    }
    UNION
    { 
     target: wdt:P921/wdt:P279 ?topic .
     BIND(3 AS ?score_)
    }
    UNION
    {
      # Topic of a cited work
      target: wdt:P2860/wdt:P921 ?topic .
      BIND(1 AS ?score_)
    }
    UNION
    {
      SELECT (1 AS ?score_) ?topic WHERE {
        ?citing_work wdt:P2860 target: .
        ?citing_work wdt:P921 ?topic . 
      }
    }
  }
  GROUP BY ?topic
} AS %results 
WHERE {
  INCLUDE %results
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en,da,de,es,jp,no,ru,sv,zh". }
}
ORDER BY DESC(?score)
LIMIT 200

graph TD