236

• License: https://www.gnu.org/licenses/gpl-3.0

• Uses method in: https://github.com/WDscholia/scholia/tree/master/scholia/app/templates/wikiproject_topics.sparql

rq turtle/ttl

Wikiproject aspect: topics

Use at

• https://query.wikidata.org/sparql

PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
#defaultView:Table

PREFIX target: <http://www.wikidata.org/entity/Q60687720>

SELECT ?count (CONCAT("/topics/Q60687720,", SUBSTR(STR(?topic), 32)) AS ?countUrl)
       ?topic ?topicLabel (CONCAT("/topic/", SUBSTR(STR(?topic), 32)) AS ?topicUrl)
       ?example_work ?example_workLabel (CONCAT("/work/", SUBSTR(STR(?example_work), 32)) AS ?example_workUrl)
WITH {
  SELECT (COUNT(?work) AS ?count) ?topic (SAMPLE(?work) AS ?example_work) WHERE {
    # Find works for the specific queried topic
	  VALUES ?p { wdt:P6104 wdt:P5008 }
	  SERVICE bd:sample { ?work ?p target: . bd:serviceParam bd:sample.limit 10000 }
    
    # Find co-occuring topics
    ?work wdt:P921 ?topic .
    
    # Avoid listing the queried topic
      FILTER (target: != ?topic)
  }
  GROUP BY ?topic
} AS %result
WHERE {
  # Label the results
  INCLUDE %result
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en" . } 
}
ORDER BY DESC(?count)

graph TD