228

• License: https://www.gnu.org/licenses/gpl-3.0

• Uses method in: https://github.com/WDscholia/scholia/tree/master/scholia/app/templates/wikiproject_co-occurring-wikiprojects.sparql

rq turtle/ttl

Wikiproject aspect: co occurring wikiprojects

Use at

• https://query.wikidata.org/sparql

PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
#defaultView:Table

PREFIX target: <http://www.wikidata.org/entity/Q60687720>

SELECT ?count
       ?wikiproject ?wikiprojectLabel (CONCAT("/wikiproject/", SUBSTR(STR(?wikiproject), 32)) AS ?wikiprojectUrl)
       ?example_entity ?example_entityLabel (CONCAT("/", SUBSTR(STR(?example_entity), 32)) AS ?example_entityUrl)
WITH {
  SELECT (COUNT(?work) AS ?count) ?wikiproject (SAMPLE(?work) AS ?example_entity) WHERE {
    # Find works for the specific queried wikiproject
	  VALUES ?p { wdt:P6104 wdt:P5008 }
	  SERVICE bd:sample { ?work ?p target: . bd:serviceParam bd:sample.limit 100000 }
    
    # Find co-occuring wikiprojects
    ?work ?p ?wikiproject .
    
    # Avoid listing the queried wikiproject
      FILTER (target: != ?wikiproject)
  }
  GROUP BY ?wikiproject
} AS %result
WHERE {
  # Label the results
  INCLUDE %result
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en" . }
}
ORDER BY DESC(?count)

graph TD