216

• License: https://www.gnu.org/licenses/gpl-3.0

• Uses method in: https://github.com/WDscholia/scholia/tree/master/scholia/app/templates/venue_most-cited-articles.sparql

rq turtle/ttl

Venue aspect: Most cited articles published in specific venue

Use at

• https://query.wikidata.org/sparql

PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
# title: Most cited articles published in specific venue

PREFIX target: <http://www.wikidata.org/entity/Q6294930>

#defaultView:Table
SELECT
  ?count
  ?work ?workLabel
  ?example_citing_work ?example_citing_workLabel
WITH {
  # Count citations
  SELECT
    (COUNT(?citing_work) AS ?count)
    ?work
    (SAMPLE(?citing_work) AS ?example_citing_work)
  WHERE {
    ?work wdt:P1433 target: .
    ?citing_work wdt:P2860 ?work.
  }
  GROUP BY ?work
  ORDER BY DESC(?count)
  LIMIT 1000  
} AS %result
WHERE {
  # Label results
  INCLUDE %result
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en" . } 
}
ORDER BY DESC(?count)

graph TD