212

• License: https://www.gnu.org/licenses/gpl-3.0

• Uses method in: https://github.com/WDscholia/scholia/tree/master/scholia/app/templates/venue_citing-venues.sparql

rq turtle/ttl

Venue aspect: Venues citing articles from this specific journal

Use at

• https://query.wikidata.org/sparql

PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
# title: Venues citing articles from this specific journal

PREFIX target: <http://www.wikidata.org/entity/Q6294930>

#defaultView:Table
SELECT
  ?count
  ?short_name
  ?citing_journal ?citing_journalLabel 
WITH {
  SELECT
    (COUNT(?citing_work) AS ?count)
    ?citing_journal
    (SAMPLE(?short_name_) AS ?short_name)
  WHERE {
    ?work wdt:P1433 target: .
    ?citing_work wdt:P2860 ?work .
    ?citing_work wdt:P1433 ?citing_journal .
    OPTIONAL { ?citing_journal wdt:P1813 ?short_name_ . }
  }
  GROUP BY ?citing_journal
  ORDER BY DESC(?count)
  LIMIT 1000
} AS %result
WHERE {
  INCLUDE %result
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en" . } 
}
ORDER BY DESC(?count)

graph TD