200

• License: https://www.gnu.org/licenses/gpl-3.0

• Uses method in: https://github.com/WDscholia/scholia/tree/master/scholia/app/templates/use_recent-work-using-the-used.sparql

rq turtle/ttl

Use aspect: recent work using the used

Use at

• https://query.wikidata.org/sparql

PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX target: <http://www.wikidata.org/entity/Q1769726>

SELECT
  ?publication_date 
  ?work ?workLabel (CONCAT("/work/", SUBSTR(STR(?work), 32)) AS ?workUrl)
WITH{
  SELECT
    ?publication_datetime
    ?work
  WHERE {
    ?work wdt:P4510 / wdt:P279* target: ;
          wdt:P577 ?publication_datetime .
  }
  ORDER BY DESC(?publication_datetime)
  LIMIT 1000
} AS %result
WHERE {
  INCLUDE %result
  BIND(xsd:date(?publication_datetime) AS ?publication_date)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en" }
}
ORDER BY DESC(?publication_date)

graph TD