199

• License: https://www.gnu.org/licenses/gpl-3.0

• Uses method in: https://github.com/WDscholia/scholia/tree/master/scholia/app/templates/use_co-used.sparql

rq turtle/ttl

Use aspect: co used

Use at

• https://query.wikidata.org/sparql

PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX target: <http://www.wikidata.org/entity/Q1769726>

SELECT
  ?count
  
  ?coused ?cousedLabel (CONCAT("/use/", SUBSTR(STR(?coused), 32)) AS ?cousedUrl)
  ("🔎" AS ?zoom)
  (CONCAT("../uses/Q1769726,", SUBSTR(STR(?coused), 32)) AS ?zoomUrl)
  ?cousedDescription
  
  ?example_work ?example_workLabel (CONCAT("/work/", SUBSTR(STR(?example_work), 32)) AS ?example_workUrl)
WITH {
  # Find works that are using a specific software,
  # and find other software used in the found works
  SELECT
    ?coused
    (COUNT(DISTINCT ?work) as ?count)
    (SAMPLE(?work) AS ?example_work)
  WHERE {
    ?work wdt:P4510 / wdt:P279* target: ;
          wdt:P4510 ?coused .
    FILTER (?coused != target:)
  }
  GROUP BY ?coused
} AS %result
WHERE {
  # Label the result
  INCLUDE %result
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en" . }
}
ORDER BY DESC(?count) 

graph TD