176

• License: https://www.gnu.org/licenses/gpl-3.0

• Uses method in: https://github.com/WDscholia/scholia/tree/master/scholia/app/templates/taxon_metabolome.sparql

rq turtle/ttl

Taxon aspect: metabolome

Use at

• https://query.wikidata.org/sparql

PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://wikidata.org/entity/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX target: <http://www.wikidata.org/entity/Q12024>

SELECT DISTINCT
  ?metabolite ?metaboliteLabel ?metaboliteChemicalStructure ?metaboliteDescription
WITH {
  SELECT DISTINCT ?children WHERE {
      ?children (wdt:P171*) target:.
  }
} AS %taxa 
WITH {
  SELECT DISTINCT ?metabolite ?metaboliteChemicalStructure WHERE {
    INCLUDE %taxa
    { ?metabolite wdt:P703 ?children }
    VALUES ?chemical { wd:Q113145171 wd:Q59199015 }
    ?metabolite wdt:P31 ?chemical .
    OPTIONAL { ?metabolite wdt:P233 ?canSmiles }
    OPTIONAL { ?metabolite wdt:P2017 ?isoSmiles }
    BIND(COALESCE(?isoSmiles, ?canSmiles) AS ?metaboliteChemicalStructure)
  }
} AS %results {
  INCLUDE %results
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". }
}

graph TD