164

• License: https://www.gnu.org/licenses/gpl-3.0

• Uses method in: https://github.com/WDscholia/scholia/tree/master/scholia/app/templates/software_dependent-software.sparql

rq turtle/ttl

Software aspect: dependent software

Use at

• https://query.wikidata.org/sparql

PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX target: <http://www.wikidata.org/entity/Q1635410>

SELECT 
  ?count 
  ?software ?softwareLabel ?softwareDescription (CONCAT("/software/", SUBSTR(STR(?software), 32)) AS ?softwareUrl)
WITH {
  SELECT 
    (COUNT(?other_software) AS ?count)
    ?software 
  {
    ?software wdt:P1547+ target: .
    OPTIONAL {
      ?other_software wdt:P1547+ ?software .
    } 
  }
  GROUP BY ?software
  ORDER BY DESC(?count)
  LIMIT 500
} AS %result
WHERE {
  INCLUDE %result
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". }
}
ORDER BY DESC(?count)

graph TD