155

• License: https://www.gnu.org/licenses/gpl-3.0

• Uses method in: https://github.com/WDscholia/scholia/tree/master/scholia/app/templates/publisher_citations-works.sparql

rq turtle/ttl

Publisher aspect: citations works

Use at

• https://query.wikidata.org/sparql

PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
#defaultView:ScatterChart

PREFIX target: <http://www.wikidata.org/entity/Q73820>

SELECT ?work_count ?citation_count ?journal ?journalLabel 
WITH {
  SELECT ?work_count ?citation_count ?journal {
    {
      SELECT ?journal (COUNT(?work) AS ?work_count) {
  	    ?journal wdt:P123 target: .
  	    ?work wdt:P1433 ?journal .
      }
      GROUP BY ?journal 
    }
    {
      SELECT ?journal (COUNT(?citing_work) AS ?citation_count) {
  	    ?journal wdt:P123 target: .
  	    ?work wdt:P1433 ?journal .
        ?citing_work wdt:P2860 ?work . 
      }
      GROUP BY ?journal 
    } 
  }
} AS %result
WHERE {
  INCLUDE %result
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en" . } 
}

graph TD