143

• License: https://www.gnu.org/licenses/gpl-3.0

• Uses method in: https://github.com/WDscholia/scholia/tree/master/scholia/app/templates/project_recent-articles.sparql

rq turtle/ttl

Project aspect: recent articles

Use at

• https://query.wikidata.org/sparql

PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX prov: <http://www.w3.org/ns/prov#>
PREFIX pr: <http://www.wikidata.org/prop/reference/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX target: <http://www.wikidata.org/entity/Q27990087>

SELECT ?date ?work ?workLabel ?type ?topics
WITH {
  SELECT DISTINCT ?work WHERE {
    {
      ?work wdt:P921 / (wdt:P527+ | wdt:P1269+ | (wdt:P31* / wdt:P279*) ) target: .
    }
    UNION
    {
      # Works funded by the project, - recursively
      ?work wdt:P859+ target: .
    }
    UNION
    {
      # Works funded by the project, - recursively
      ?work wdt:P859/(wdt:P1344|^wdt:P710)* target: .
    }
    UNION {
      target: ?propp ?statement .
      ?statement a wikibase:BestRank ;
                 prov:wasDerivedFrom/pr:P248 ?work .
    }
  }
} AS %works
WITH {
  SELECT
    (MAX(?dates) as ?datetime)
    ?work
    (GROUP_CONCAT(DISTINCT ?type_label; separator=", ") AS ?type)
    (GROUP_CONCAT(?topic_label; separator=" // ") AS ?topics)
  WHERE {
    INCLUDE %works
    OPTIONAL {
       ?work wdt:P31 ?type_ .
       ?type_ rdfs:label ?type_label . FILTER (LANG(?type_label) = 'en')
    }
    OPTIONAL { ?work wdt:P577 ?dates . }
    OPTIONAL {
      ?work wdt:P921 ?topic .
      ?topic rdfs:label ?topic_label . FILTER (lang(?topic_label) = 'en')
    }
  }
  GROUP BY ?work
} AS %result
WHERE {
  INCLUDE %result
  BIND(xsd:date(?datetime) AS ?date)
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en" .
  }
}
ORDER BY DESC(?date)
LIMIT 500

graph TD