130

• License: https://www.gnu.org/licenses/gpl-3.0

• Uses method in: https://github.com/WDscholia/scholia/tree/master/scholia/app/templates/podcast-language_recent-episodes.sparql

rq turtle/ttl

Podcast-language aspect: recent episodes

Use at

• https://query.wikidata.org/sparql

PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://wikidata.org/entity/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX target: <http://www.wikidata.org/entity/Q7411>

SELECT ?publication_date 
  ?podcast ?podcastLabel (CONCAT("/podcast/", SUBSTR(STR(?podcast), 32)) AS ?podcastUrl)
  ?episode ?episodeLabel (CONCAT("/podcast-episode/", SUBSTR(STR(?episode), 32)) AS ?episodeUrl)
WITH {
  SELECT DISTINCT ?episode ?podcast (MIN(?publication_date_) AS ?publication_date) WHERE {
    ?episode wdt:P31 wd:Q61855877 ; wdt:P179 ?podcast .
    ?podcast wdt:P407 target: .
    OPTIONAL {
      ?episode wdt:P577 ?publication_datetime .
      BIND(xsd:date(?publication_datetime) AS ?publication_date_)
    }
  } GROUP BY ?episode ?podcast
    ORDER BY DESC(?publication_date)
    LIMIT 50
} AS %EPISODES WHERE {
  INCLUDE %EPISODES
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". }
} GROUP BY ?publication_date ?episode ?episodeLabel ?podcast ?podcastLabel
  ORDER BY DESC(?publication_date)

graph TD