099

• License: https://www.gnu.org/licenses/gpl-3.0

• Uses method in: https://github.com/WDscholia/scholia/tree/master/scholia/app/templates/gene_variants.sparql

rq turtle/ttl

Gene aspect: variants

Use at

• https://query.wikidata.org/sparql

PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX target: <http://www.wikidata.org/entity/Q14860818>

SELECT
  ?variant ?variantLabel ?variantDescription
  ?types
WITH {
  SELECT ?variant ?type
  WHERE {
    ?variant wdt:P3433 target:
  }
} AS %variants
WITH {
  SELECT ?variant (GROUP_CONCAT(?type_label; separator=" // ") AS ?types) WHERE {
    INCLUDE %variants
    OPTIONAL {
      ?variant wdt:P279 ?variantType . 
      ?variantType rdfs:label ?type_label .  FILTER (lang(?type_label) = 'en')
    }
  }
  GROUP BY ?variant
} AS %result 
WHERE {
  INCLUDE %result
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". }
}

graph TD