059

• License: https://www.gnu.org/licenses/gpl-3.0

• Uses method in: https://github.com/WDscholia/scholia/tree/master/scholia/app/templates/country_co-organizations.sparql

rq turtle/ttl

Country aspect: Co-organizations for a specific country

Use at

• https://query.wikidata.org/sparql

PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
# title: Co-organizations for a specific country
PREFIX target: <http://www.wikidata.org/entity/Q35>

#defaultView:Map
SELECT ?coorganization ?coorganizationLabel ?geocoordinates ?example_coauthor ?example_coauthorLabel ?example_work ?example_workLabel
WITH {  
  SELECT
    ?coorganization
    (SAMPLE(?geocoordinates_) AS ?geocoordinates)
    (SAMPLE(?coauthor) AS ?example_coauthor)
    (SAMPLE(?work) AS ?example_work)
  WHERE {
    ?organization wdt:P17 target: .
    ?author wdt:P108 | wdt:P463 | wdt:P1416/wdt:P361* ?organization .
    ?work wdt:P50 ?author, ?coauthor .
    ?coauthor wdt:P108 | wdt:P463 | wdt:P1416/wdt:P361* ?coorganization .
    FILTER NOT EXISTS { ?coorganization wdt:P17 target: }
    ?coorganization wdt:P625 ?geocoordinates_ .
  }
  GROUP BY ?coorganization 
} AS %results
WHERE {
  INCLUDE %results
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". }
}

graph TD