045

• License: https://www.gnu.org/licenses/gpl-3.0

• Uses method in: https://github.com/WDscholia/scholia/tree/master/scholia/app/templates/chemical_identifiers.sparql

rq turtle/ttl

Chemical aspect: identifiers for this chemical

Use at

• https://query.wikidata.org/sparql

PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://wikidata.org/entity/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX target: <http://www.wikidata.org/entity/Q2270>

# title: identifiers for this chemical
SELECT
  ?Identifier ?IdentifierLabel
  ?Value (SAMPLE(?idUrls) as ?ValueUrl)
  ?IdentifierDescription
WITH {
  SELECT ?Identifier ?Value ?formatterurl WHERE {
    target: ?IDdir ?Value .
    ?Identifier wikibase:directClaim ?IDdir ;
            wdt:P31 wd:Q19833835 .
    OPTIONAL { 
      ?Identifier wdt:P1630 ?formatterurl .
    }
    FILTER (?Identifier != wd:P233)
    FILTER (?Identifier != wd:P234)
    FILTER (?Identifier != wd:P2017)
  } LIMIT 500
} AS %RESULTS {
  { SELECT * WHERE {
      INCLUDE %RESULTS
      FILTER (?Identifier = wd:P234)
      BIND(IRI(REPLACE(?formatterurl, '\\$1', ENCODE_FOR_URI(str(?Value)))) AS ?idUrls).
    }
  } UNION {
    SELECT * WHERE {
      INCLUDE %RESULTS
      FILTER (?Identifier != wd:P234)
      BIND(IRI(REPLACE(?formatterurl, '\\$1', str(?Value))) AS ?idUrls).
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". }
}
GROUP BY ?Identifier ?IdentifierLabel ?IdentifierDescription ?Value
ORDER BY ASC(?IdentifierLabel)

graph TD