026

• License: https://www.gnu.org/licenses/gpl-3.0

• Uses method in: https://github.com/WDscholia/scholia/tree/master/scholia/app/templates/award_list-of-recipients.sparql

rq turtle/ttl

Award aspect: list of recipients

Use at

• https://query.wikidata.org/sparql

PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX target: <http://www.wikidata.org/entity/Q44585>

SELECT
  ?year
  ?recipient ?recipientLabel ?recipientDescription
  ?example_work ?example_workLabel
WITH {
  SELECT DISTINCT ?recipient ?year (SAMPLE(?work) AS ?example_work) WHERE {
    ?recipient p:P166 ?award_statement . 
    ?award_statement ps:P166 target: .
    OPTIONAL {
      { ?award_statement pq:P585 ?time }
      UNION
      { ?award_statement pq:P580 ?time }
      BIND(YEAR(?time) AS ?year)
    }
    OPTIONAL { ?work wdt:P50 ?recipient . }
  }
  GROUP BY ?recipient ?year
} AS %result
WHERE {
  INCLUDE %result 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en,da,de,es,fr,jp,no,ru,sv,zh" . }  
}
ORDER BY DESC(?year)
LIMIT 10000

graph TD